[GAP Forum] Computing conjugacy classes on matrix groups over finite fields

[Thomas Breuer]

Dear Forum,

since Siddharta asked about conjugay of elements in a group,
without mentioning the context of character tables,
I would propose just to use 'IsConjugate'.

    gap> x:= [ [1,1,0], [0,1,0], [0,0,1] ] * Z(2);;
    gap> y:= [ [0,0,1], [1,0,0], [0,1,0] ] * Z(2);;
    gap> g:= Group( x, y );;
    gap> Size( g );
    168
    gap> xy:= x * y;;
    gap> Order( xy );
    7
    gap> ccl:= ConjugacyClasses( g );;
    gap> reps:= List( ccl, Representative );;
    gap> List( reps, Order );
    [ 1, 2, 4, 7, 7, 3 ]
    gap> xy in ccl[4];
    true
    gap> xy in ccl[5];
    false

I think that it makes no sense to ask in which of the two classes
the element 'xy' lies, unless one has defined what ``the first of the
two classes'' means.
Note that there is a group automorphism that swaps the two classes.
But once you have fixed a class, you can ask whether 'xy' lies in that class.

    gap> IsConjugate( g, xy, reps[4] );
    true

And it makes sense to ask whether some power of 'xy' is conjugate to 'xy'.

    gap> List( [ 1 .. 6 ], i -> IsConjugate( g, xy^i, xy ) );
    [ true, true, false, true, false, false ]

All the best,
Thomas


On Wed, Jan 29, 2020 at 01:00:24AM -0300, Fernando Fantino wrote:
> Dear  Siddhartha,
> 
> I think that the commands:
> ClassMultiplicationCoefficient
> <https://www.gap-system.org/Manuals/doc/ref/chap71.html#X7E2EA9FE7D3062D3>
> and
> PowerMap
> <https://www.gap-system.org/Manuals/doc/ref/chap73.html#X781FAA497E3B4D1A>
> can help with your task.
> 
> Sincerely,
> Fernando.
> 
> 
> 
> 
> El lun., 27 ene. 2020 a las 8:50, Siddhartha Sarkar (<siddhartha18 at gmail.com>)
> escribió:
> 
> > Dear forum,
> >
> > Consider the group L_3(2) which is generated by the following two matrices:
> >
> > X = [1,1,0; 0,1,0; 0,0,1], Y = [0,0,1; 1,0,0; 0,1,0]
> >
> > of order 2 and 3 whose product has order 7. Now L_3(2) has two order 7
> > classes 7A and 7B.
> >
> > (1) Is it possible to compute in GAP in which conjugacy class the product
> > XY goes to?
> >
> > (2) Secondly, I wish to pick an arbitrary element either from 7A or from
> > 7B, look at its various powers and check whether these goes in the class
> > containing XY. How is it done in GAP?
> >
> > I can see that the SmallGroup in GAP stores the information on conjugacy
> > classes in a very different way. (I do not have access to MAGMA, by the
> > way.)
> >
> > Regards,
> > Siddhartha
> > _______________________________________________
> > Forum mailing list
> > Forum at gap-system.org
> > https://mail.gap-system.org/mailman/listinfo/forum
> >
> _______________________________________________
> Forum mailing list
> Forum at gap-system.org
> https://mail.gap-system.org/mailman/listinfo/forum