[GAP Forum] Sylow 7-subgroup of the Monster

[Benjamin Sambale]

Dear Thomas,

thanks a lot for your help! In the mean time, Burkhard Külshammer and I 
determined the isomorphism type by theoretical arguments. In case this 
is of any interest, the Sylow 7-subgroup of the Monster is characterized 
by the following data:

Size: 7^6,
Exponent: 7,
7-Rank: 3,
contains 7^{1+4}_+.

Best wishes,
Benjamin


Am 24.10.2012 09:25, schrieb Thomas Breuer:
> Dear Benjamin, dear GAP Forum,
>
> if the embedding into the Monster group need not be explicit
> then the following works.
>
> The current version of GAP's character table library contains
> a few character tables of subgroups of the Monster group
> that contain a Sylow 7 subgroup of the Monster group.
>
>      gap> m:= CharacterTable( "M" );
>      CharacterTable( "M" )
>      gap> Collected( Factors( Size( m ) ) );
>      [ [ 2, 46 ], [ 3, 20 ], [ 5, 9 ], [ 7, 6 ], [ 11, 2 ], [ 13, 3 ],
>        [ 17, 1 ], [ 19, 1 ], [ 23, 1 ], [ 29, 1 ], [ 31, 1 ], [ 41, 1 ],
>        [ 47, 1 ], [ 59, 1 ], [ 71, 1 ] ]
>      gap> src:= NamesOfFusionSources( m );;
>      gap> srctbls:= List( src, CharacterTable );;
>      gap> filt:= Filtered( srctbls, x -> Size( x ) mod 7^6 = 0 );
>      [ CharacterTable( "7^(2+1+2):GL2(7)" ),
>        CharacterTable( "7^(1+4):(3x2.S7)" ), CharacterTable( "7^1+4.2A7" ) ]
>
> For some of these character tables, a construction of the corresponding
> group is known.
>
>      gap> info:= List( filt, GroupInfoForCharacterTable );
>      [ [ [ "AtlasGroup", [ "7^(2+1+2):GL2(7)" ] ] ],
>        [ [ "AtlasGroup", [ "7^(1+4):(3x2.S7)" ] ] ], [  ] ]
>      gap> g:= GroupForGroupInfo( info[1][1] );
>      <permutation group of size 33882912 with 2 generators>
>      gap> syl:= SylowSubgroup( g, 7 );
>      <permutation group of size 117649 with 6 generators>
>      gap> pc:= Image( IsomorphismPcGroup( syl ) );
>      Group([ f1, f2, f3, f4, f5, f6 ])
>
> I hope this helps.
>
> All the best,
> Thomas
>
>
> On Tue, Oct 23, 2012 at 01:06:50PM +0200, Benjamin wrote:
>> Dear all,
>>
>> how can I construct a Sylow 7-subgroup of the Monster group in GAP?
>>
>> Best wishes,
>> Benjamin
>