[GAP Forum] computing orbit

[William DeMeo]

Dear Vipul,

For the specific action you describe (conjugation action on the set of
subgroups), the short answer is to just count the number of conjugacy
classes of subgroups.  For example:

gap> g:=AlternatingGroup(4);;
gap> cc:=ConjugacyClassesSubgroups(g);;
gap> Size(cc);
5

(N.B. This count includes the "trivial" classes ()^G and G^G.)

If you want, you can ask GAP to describe the structure of
representatives of these conjugacy classes of subgroups:

gap> List(cc, x->StructureDescription(Representative(x)));
[ "1", "C2", "C3", "C2 x C2", "A4" ]

I'm sure it's also possible to compute the number of orbits of
subgroups under conjugation action by actually defining the action
group and using the Orbits command.  Maybe someone else will reply and
describe that.

As for the action of a group on the set of cosets of a subgroup, of
course, this always results in a single orbit, so maybe isn't the
action you're interested in...  unless you consider this action on
blocks of imprimitivity, in which case you do have orbits (the systems
of imprimitivity).  Here's an example:

gap> G:=SymmetricGroup(4);;
gap> cc:=ConjugacyClassesSubgroups(G);;
gap> H:=Representative(cc[3]);   # Group([ (3,4) ])
gap> act:=Action(G,RightCosets(G,H),OnRight);
gap> blks:=AllBlocks(act);
[ [ 1, 2, 3 ], [ 1, 4, 10 ], [ 1, 5, 9, 11 ], [ 1, 9 ] ]

To see the full orbits (systems of imprimitivity), use

gap> Orbit(act,blks[1],OnSets);
[ [ 1, 2, 3 ], [ 7, 8, 9 ], [ 10, 11, 12 ], [ 4, 5, 6 ] ]
gap> Orbit(act,blks[2],OnSets);
[ [ 1, 4, 10 ], [ 2, 5, 8 ], [ 6, 9, 12 ], [ 3, 7, 11 ] ]

etc.

Hope that helps!

-William


On Sun, May 15, 2011 at 8:53 PM, vipul kakkar <vplkakkar at gmail.com> wrote:
> Dear all
> Can I do following in GAP and how:
>
> Let G be a group and X be a set on which G acts, I want to calculate number
> of orbits .
> for example : Let G be any(finite) group and X the set of all subgroups of G
> and G acts on X by conjugation and I want to compute number of orbit w.r.t
> this action.
>
> Thanks
> _______________________________________________
> Forum mailing list
> Forum at mail.gap-system.org
> http://mail.gap-system.org/mailman/listinfo/forum
>