[GAP Forum] About Normalizer

[Stefan Kohl]

Dear Forum,

Dung Duong asked:

> I have a group G:=AutomorphismGroup(PSL(2,9)). One of its Maximal subgroup
> is $M =N_G(D_8)$. And I would like to compute the order of this group. So I
> did as follows :
>
> > G:=AutomorphismGroup(PSL(2,9));
> > H:=DihedralGroup(8);
> > Normalizer(G,H);
>
> But it does not work. I think that somehow I need to "embed" H as a subgroup
> of G. But I dont know how.
>
> Please tell me how I can do.

You can proceed as follows:

1. Enter your groups:

gap> G := AutomorphismGroup(PSL(2,9));
<group with 4 generators>
gap> H := DihedralGroup(IsPermGroup,8);
Group([ (1,2,3,4), (2,4) ])

2. Switch to an isomorphic permutation group, as computations
   in permutation groups are faster:

gap> phi := IsomorphismPermGroup(G);
MappingByFunction( <group with 4 generators>, Group(
[ (3,9,4,6)(5,10,8,7), (1,2,4)(5,6,8)(7,9,10), (1,2)(3,10,6,5,4,7,9,8),
  (1,2)(5,8)(7,10) ]), function( auto ) ... end, function( elm ) ... end )
gap> Gp := Image(phi);
Group([ (3,9,4,6)(5,10,8,7), (1,2,4)(5,6,8)(7,9,10), (1,2)(3,10,6,5,4,7,9,8),
  (1,2)(5,8)(7,10) ])

3. Compute all embeddings of H into G up to conjugacy:

gap> embs := IsomorphicSubgroups(Gp,H);
[ [ (1,3), (1,4)(2,3) ] ->
    [ (1,4)(2,10)(3,9)(5,6)(7,8), (1,4)(2,8)(3,6)(5,10)(7,9) ],
  [ (1,3), (1,4)(2,3) ] -> [ (1,4)(2,8)(3,6)(5,10)(7,9), (1,4)(6,8)(9,10) ],
  [ (1,3), (1,4)(2,3) ] -> [ (1,2)(3,4)(5,7)(8,10), (2,3)(5,7)(6,8)(9,10) ],
  [ (1,3), (1,4)(2,3) ] -> [ (2,5)(3,10)(4,6)(7,9), (1,4)(6,8)(9,10) ],
  [ (1,3), (1,4)(2,3) ] -> [ (1,8)(3,10)(7,9), (1,4)(6,8)(9,10) ] ]

4. Compute the corresponding normalizers and find out which of them
   are maximal subgroups of G:

gap> norms := List(embs,emb->Normalizer(Gp,Image(emb)));
[ Group([ (2,7,3,5)(6,9,8,10), (2,3)(5,7)(6,8)(9,10),
      (1,4)(2,10)(3,9)(5,6)(7,8), (1,4)(5,7)(6,10)(8,9), (5,7)(6,9)(8,10) ]),
  Group([ (2,8,3,6)(5,10,7,9), (2,3)(5,7)(6,8)(9,10),
      (1,4)(2,8)(3,6)(5,10)(7,9), (2,5,3,7)(6,10,8,9) ]),
  Group([ (2,3)(5,7)(6,8)(9,10), (1,3)(2,4)(5,7)(6,9), (1,2)(3,4)(5,7)(8,10),
      (2,3)(6,10)(8,9), (1,6,2,10,4,9,3,8) ]),
  Group([ (1,4)(6,8)(9,10), (1,8)(3,7)(4,6)(9,10), (2,5)(3,10)(4,6)(7,9),
      (1,8)(3,10)(7,9) ]),
  Group([ (1,4)(6,8)(9,10), (3,9)(4,6)(7,10), (1,8)(3,10)(7,9),
      (1,3,6,9,8,7,4,10), (2,5)(3,10)(4,6)(7,9) ]) ]
gap> maxes := MaximalSubgroupClassReps(Gp);
[ Group([ (5,7)(6,9)(8,10), (3,4)(5,8)(6,9)(7,10), (3,6,4,9)(5,7,8,10),
      (3,5,4,8)(6,10,9,7), (1,2)(5,8)(7,10) ]),
  Group([ (1,2)(3,5)(4,8)(6,10)(7,9), (1,5,9,6,8)(2,3,7,10,4),
      (3,4)(5,8)(6,9)(7,10), (3,7,4,10)(5,9,8,6) ]),
  Group([ (2,9,6)(3,8,10)(4,7,5), (5,7)(6,9)(8,10), (2,8,5)(3,7,6)(4,9,10),
      (3,4)(5,10)(7,8), (3,9,4,6)(5,10,8,7), (3,5,4,8)(6,10,9,7) ]),
  Group([ (1,8)(3,7)(4,6)(9,10), (1,4,3,6,5)(2,9,8,10,7), (5,7)(6,9)(8,10) ]),
  Group([ (1,8)(3,7)(4,6)(9,10), (1,4,3,6,5)(2,9,8,10,7), (3,5,4,8)(6,10,9,7) ]),
  Group([ (1,8)(3,7)(4,6)(9,10), (1,4,3,6,5)(2,9,8,10,7), (3,5,6,7,4,8,9,10) ]) ]
gap> Mp := Filtered(norms,N->ForAny(maxes,M->IsConjugate(Gp,N,M)));
[ Group([ (2,7,3,5)(6,9,8,10), (2,3)(5,7)(6,8)(9,10),
      (1,4)(2,10)(3,9)(5,6)(7,8), (1,4)(5,7)(6,10)(8,9), (5,7)(6,9)(8,10) ]),
  Group([ (2,3)(5,7)(6,8)(9,10), (1,3)(2,4)(5,7)(6,9), (1,2)(3,4)(5,7)(8,10),
      (2,3)(6,10)(8,9), (1,6,2,10,4,9,3,8) ]),
  Group([ (1,4)(6,8)(9,10), (3,9)(4,6)(7,10), (1,8)(3,10)(7,9),
      (1,3,6,9,8,7,4,10), (2,5)(3,10)(4,6)(7,9) ]) ]
gap> List(Mp,IdGroup); # there are 3, but they are isomorphic
[ [ 32, 43 ], [ 32, 43 ], [ 32, 43 ] ]

5. Go back to G by taking preimages under the isomorphism to the
   permutation group:

gap> M := PreImage(phi,Mp[1]);
<group of size 32 with 5 generators>
gap> GeneratorsOfGroup(M);
[ ^(2,7,3,5)(6,9,8,10), ^(2,3)(5,7)(6,8)(9,10), ^(1,4)(2,10)(3,9)(5,6)(7,8),
  ^(1,4)(5,7)(6,10)(8,9), ^(5,7)(6,9)(8,10) ]
gap> StructureDescription(M);
"(C2 x D8) : C2"

Hope this helps,

    Stefan Kohl

-------------------------------------------------------------------
Dr. Stefan Kohl

Current address:
Universiteti "Ismail Qemali" Vlore
Lagjja: Pavaresia
Vlore / Albania

Web: http://www.gap-system.org/DevelopersPages/StefanKohl/
-------------------------------------------------------------------