[GAP Forum] group action on polynomials

[Alexander Hulpke]

Dear Bill Chin, dear forum,

> I have defined a polynomial ring Q[x_1,...,x_5] over the rationals. How do
> you define an action of S_5 such that gx_i=x_g(i) for all g in S_5, i.e. an
> action permuting the vertices? I am interested in this and other actions on
> the polynomial ring.
> 
> I have defined
> 
> Q:=Rationals
> R:=PolynomialRing(Q,5)
> G:=Group[(12),(1,2,3,4,5)]

With these definitions (correcting the syntax for the group definition, of course) you can use the action `OnIndeterminates' to compute orbits or stabilizers him and, for example.

gap> ind:=IndeterminatesOfPolynomialRing(R);
[ x_1, x_2, x_3, x_4, x_5 ]
gap> pol:=ind[2]*ind[3]+ind[4]*ind[5];
x_2*x_3+x_4*x_5
gap> s:=Stabilizer(G,pol,OnIndeterminates);
Group([ (2,4)(3,5), (4,5) ])
gap> Size(s);
8
gap> Orbit(G,pol,OnIndeterminates);
[ x_2*x_3+x_4*x_5, x_1*x_3+x_4*x_5, x_1*x_5+x_3*x_4, x_1*x_5+x_2*x_4, 
  x_2*x_5+x_3*x_4, x_1*x_2+x_4*x_5, x_1*x_4+x_2*x_5, x_1*x_2+x_3*x_5, 
  x_1*x_5+x_2*x_3, x_1*x_3+x_2*x_5, x_1*x_4+x_2*x_3, x_1*x_2+x_3*x_4, 
  x_1*x_3+x_2*x_4, x_2*x_4+x_3*x_5, x_1*x_4+x_3*x_5 ]
gap> u:=Subgroup(G,[(1,2,3),(2,3,4)]);
Group([ (1,2,3), (2,3,4) ])
gap> o:=Orbit(u,ind[1]*ind[2],OnIndeterminates);
[ x_1*x_2, x_2*x_3, x_1*x_3, x_3*x_4, x_1*x_4, x_2*x_4 ]
gap> inv:=Sum(o);
x_1*x_2+x_1*x_3+x_1*x_4+x_2*x_3+x_2*x_4+x_3*x_4
gap> s:=Stabilizer(G,inv,OnIndeterminates);
Group([ (1,2), (1,2,3,4) ])
gap> Size(s);
24
gap> Index(s,u);
2

 I hope this is of help. Best wishes,

Alexander Hulpke




-- Colorado State University, Department of Mathematics,
Weber Building, 1874 Campus Delivery, Fort Collins, CO 80523-1874, USA
email: hulpke at math.colostate.edu, Phone: ++1-970-4914288
http://www.math.colostate.edu/~hulpke