[GAP Forum] p-group

[Derek Holt]

Dear GAP Forum, Dear Vivek,

You can use  the GAP package KBMAG to prove nilpotency of finitely presented
groups, using the method described by Charles Sims in his book of computing
in finitely presented groups. This uses the Knuth-Bendix completion
algorithm.

This process is described and illustrated in Example 4 (p. 13) of the KBMAG
manual. I have successfully verifed that your group below is nilpotent of
order p^10 for p=2,3,5,7,11,13,17, and I am trying to do 19.

Of course, since these groups are (apparently) finite, you could try
use coset enumeration. This will work for small primes such as 2 and 3, but
for larger primes the group order will probably be too large, and I think
the Sims algorithm will work better.

You first run NilpotentQuotient (as described in Bettina Eick's reply) to
find the maximal nilpotent quotient of your group. The aim is then to
prove that the group is actually isomorphic to this quotient.
You do this by introducing new generators in the presentation which
correspond the power-commutator generators in the maximal nilpotent
quotient. You order the generators so that those at the bottom of the
group come first and then use the so-called recursive ordering on strings
to run Knuth-Bendix.

Here is the basic GAP code to do this.

LoadPackage("kbmag");
SetInfoLevel(InfoRWS,2);
F:=FreeGroup("j","i","h","g","f","e","d","c","b","a");;
j:=F.1;; i:=F.2;; h:=F.3;; g:=F.4;; f:=F.5;;
e:=F.6;; d:=F.7;; c:=F.8;; b:=F.9;; a:=F.10;;
p:=3;;
rels := [a^p/e, b^p/f, c^p/d, e^p/g, f^p/h, g^p/i, i^p/j,
         j^p, h^p, d^p, Comm(a,b)/i, Comm(a,c)/d, Comm(b,c)/h ];;
G := F/rels;;
R := KBMAGRewritingSystem(G);;
SetOrderingOfKBMAGRewritingSystem(R, "recursive");
MakeConfluent(R);

If successful it will halt with a confluent presentation containing the
relations of the power-commutator presentation of the computed maximal
nilpotent quotient. You have then proved that these relations hold in
the group itself (not just in the nilptent quotient), so you have proved
that the group is nilpotent.  This consists of 65 reduction equations
(or 62 when p=2).

The above works quickly for p=2,3,5,7. For larger primes, it helps to 
restrict the length of the stored reduction relations, and then re-run
after completion. You have to experiment to find the optimal maximal
length to store.  So, for example, the following works fast for p=17:

p:=19;;
rels := [a^p/e, b^p/f, c^p/d, e^p/g, f^p/h, g^p/i, i^p/j,
         j^p, h^p, d^p, Comm(a,b)/i, Comm(a,c)/d, Comm(b,c)/h ];;
G := F/rels;;
R := KBMAGRewritingSystem(G);;
SetOrderingOfKBMAGRewritingSystem(R, "recursive");
O := OptionsRecordOfKBMAGRewritingSystem(R);
O.maxstoredlen := [40,40];
MakeConfluent(R);
Unbind(O.maxstoredlen);
MakeConfluent(R);

Derek Holt.






On Wed, Jan 27, 2010 at 08:06:38PM +0530, Vivek Jain wrote:
> Dear Forum,
> 
> I want to know that:
> 
> "Is it possible using GAP to check that given presentation is a nilpotent group of class 2 or not?"
> 
> For example $G=\langle  a,b,c| a^{p^5}, b^{p^3}, c^{p^2}, [a,b]=a^{p^3}, [a,c]=c^p, [b,c]=b^{p^2} \rangle $ where $p$ is a prime.
> 
> Also how can we determine its automorphism group using GAP?
> 
> 
> with regards
> 
> Vivek kumar jain
> 
> 
> 
> 
>       Your Mail works best with the New Yahoo Optimized IE8. Get it NOW! http://downloads.yahoo.com/in/internetexplorer/
> _______________________________________________
> Forum mailing list
> Forum at mail.gap-system.org
> http://mail.gap-system.org/mailman/listinfo/forum