[GAP Forum] semidirect product

[Alexander Hulpke]

Dear Forum,

On Jan 20, 2010, at 1/20/10 5:11, Alex Trofimuk wrote:

> How to construct a group G=[E_{3^2}\times E_{5^2}]A_4, where [A]B -- semidirect product with normal subgroup A,  A\times  B --- direct product of group A and B, E_{3^2} --- elementary abelian group of order 9, A_4 --- alternating group of degree 4.

We had a couple of such questions recently, so I'll be brief. Basically you will need to describe the action of A4 in the form of a homomorphism from A4 into the automorphism group of the direct product.

Lets construct this automorphism group first. For working with it, it is convenient to use a permutation representation instead:

gap> e1:=ElementaryAbelianGroup(3^2);                                          
<pc group of size 9 with 2 generators>
gap> e2:=ElementaryAbelianGroup(5^2);
<pc group of size 25 with 2 generators>
gap> d:=DirectProduct(e1,e2);
<pc group of size 225 with 4 generators>
gap> au:=AutomorphismGroup(d);
<group with 8 generators>
gap> Size(au);
23040
gap> auh:=IsomorphismPermGroup(au);
<action isomorphism>
gap> p:=Image(auh);
<permutation group of size 23040 with 8 generators>

As I can't think of an obvious action, lets see whether there are subgroups of the automorphism group isomorphic A4. We do this by calculating all subgroups up to conjugacy and picking the right ones.
gap> cl:=List(ConjugacyClassesSubgroups(p),Representative);;
gap> cl:=Filtered(cl,x->Size(x)=12);;
gap> IdGroup(AlternatingGroup(4)); # use to test isomorphism
[ 12, 3 ]
gap> cl:=Filtered(cl,x->IdGroup(x)=[12,3]);
[  ]

So there is no faithful action of A4. Lets try a factor group, C3:
gap> cl:=List(ConjugacyClassesSubgroups(p),Representative);;
gap> cl:=Filtered(cl,x->Size(x)=3);     
[ <permutation group of size 3 with 1 generators>, 
  <permutation group of size 3 with 1 generators>, 
  <permutation group of size 3 with 1 generators> ]

This gives us three different products.

To create the first one, e.g. create the map form A4 to the corresponding subgroup of the automorphism group
gap> acthom:=GQuotients(a4,cl[1])[1];
[ (2,4,3), (1,3,2) ] -> 
[ (3,7,17)(4,8,18)(12,38,22)(13,39,23)(14,24,40)(15,25,41)(16,26,42)(31,68,
 [...]
gap> acthom:=acthom*InverseGeneralMapping(auh);
[ (2,3,4), (2,4,3), (1,2,3), (1,3,2), (1,3,4), (1,4,3) ] -> 
[ [ f1, f1*f2, f3, f4 ] -> Pcgs([ f1, f2, f3, f4 ]), 
  [ f1, f1^2*f2, f3, f4 ] -> Pcgs([ f1, f2, f3, f4 ]), 
  [ f1, f1^2*f2, f3, f4 ] -> Pcgs([ f1, f2, f3, f4 ]), 
  [ f1, f1*f2, f3, f4 ] -> Pcgs([ f1, f2, f3, f4 ]), 
  [ f1, f1^2*f2, f3, f4 ] -> Pcgs([ f1, f2, f3, f4 ]), 
  [ f1, f1*f2, f3, f4 ] -> Pcgs([ f1, f2, f3, f4 ]) ]

Now we can from the SDP:

gap> s:=SemidirectProduct(a4,acthom,d); 
<pc group of size 2700 with 7 generators>

Regards,

   Alexander Hulpke



-- Colorado State University, Department of Mathematics,
Weber Building, 1874 Campus Delivery, Fort Collins, CO 80523-1874, USA
email: hulpke at math.colostate.edu, Phone: ++1-970-4914288
http://www.math.colostate.edu/~hulpke