[GAP Forum] transfer fp relators

[Robert F. Morse]

Max Horn wrote:
> Dear Rudolf Zlabinger,
> 
> the following program performs what you want in a reasonably simple and
> extensible fashion.
> 
> f:=FreeGroup(4);;
> s3:=SymmetricGroup(3);
> a4:=AlternatingGroup(4);;
> s3fp:=Image(IsomorphismFpGroup(s3));;
> a4fp:=Image(IsomorphismFpGroup(a4));;
> 
> s3rels:=List(RelatorsOfFpGroup(s3fp), r->MappedWord(r,
> FreeGeneratorsOfFpGroup(s3fp), [f.1,f.2]));;
> a4rels:=List(RelatorsOfFpGroup(a4fp), r->MappedWord(r,
> FreeGeneratorsOfFpGroup(a4fp), [f.3,f.4]));;
> commrels:=ListX([f.1,f.2], [f.3,f.4], Comm);;
> 
> dirprodfp:= f / Union(s3rels, a4rels,commrels);;
> dirprod:=DirectProduct(s3,a4);;
> IsomorphismGroups(dirprodfp,dirprod);
> 
> 

The direct product of two finitely presented groups will return a 
finitely presented group. Embedding and projection information is also 
available. For instance

gap> A4 := AlternatingGroup(4);
Alt( [ 1 .. 4 ] )
gap> S3 := SymmetricGroup(3);
Sym( [ 1 .. 3 ] )
gap> A4iso := IsomorphismFpGroup(A4);
[ (1,2,4), (1,3,4) ] -> [ A_4.1, A_4.2 ]
gap> S3iso := IsomorphismFpGroup(S3);
[ (1,2), (2,3) ] -> [ S_3.1, S_3.2 ]
gap> dpfp := DirectProduct(Image(A4iso),Image(S3iso));
<fp group of size 72 on the generators [ f1, f2, f3, f4 ]>
gap> Embedding(dpfp,1);
[ A_4.1, A_4.2 ] -> [ f1, f2 ]
gap> Embedding(dpfp,2);
[ S_3.1, S_3.2 ] -> [ f3, f4 ]
gap> Projection(dpfp,1);
[ f1, f2, f3, f4 ] -> [ A_4.1, A_4.2, <identity ...>, <identity ...> ]
gap> Projection(dpfp,2);
[ f1, f2, f3, f4 ] -> [ <identity ...>, <identity ...>, S_3.1, S_3.2 ]
gap> A4Embed := A4iso*Embedding(dpfp,1);
[ (1,2,4), (1,3,4) ] -> [ f1, f2 ]
gap> S3Embed := S3iso*Embedding(dpfp,2);
[ (1,2), (2,3) ] -> [ f3, f4 ]

Regards, Robert F. Morse