[GAP Forum] tensor product of lie algebra representations

[degraaf at science.unitn.it]

Dear R.N. Tsai,

You asked about decomposing a modulo over a semisimple Lie algebra:


>   How would I get a basis for the irreducible constituents of V in   
> terms of B.
>

In this case you can get the irreducible submodules by computing
their highest weight vectors. Those are the vectors that are in the
kernel of all positive root vectors. For example, we can do the
following:


gap> V1  := HighestWeightModule(L,[1,0]);
<3-dimensional left-module over <Lie algebra of dimension 8 over Rationals>>
gap> V2  := HighestWeightModule(L,[0,1]);
<3-dimensional left-module over <Lie algebra of dimension 8 over Rationals>>
gap> V:= TensorProductOfAlgebraModules( V1, V2 );
<9-dimensional left-module over <Lie algebra of dimension 8 over Rationals>>
gap> x:= ChevalleyBasis(L)[1];
[ v.1, v.2, v.3 ]

# x is a list containing the highest weight vectors. We compute their kernels:

gap> nu:= List( x, y -> NullspaceMat( TransposedMat( MatrixOfAction(  
Basis(V), y ) ) ) );;
gap> VV:= List( nu, b -> VectorSpace( Rationals, b ) );
[ <vector space over Rationals, with 5 generators>, <vector space over  
Rationals, with 5 generators>,
   <vector space over Rationals, with 5 generators> ]

# and their intersection:

gap> hwv:=BasisVectors( Basis( Intersection( VV ) ) );
[ [ 1, 0, 0, 0, 0, 0, 0, 0, 0 ], [ 0, 0, 1, 0, -1, 0, -1, 0, 0 ] ]

# Now we take the submodules generated by these vectors:

gap> M:= List( hwv, v -> SubAlgebraModule( V, [ LinearCombination(  
Basis(V), v )] ) );
[ <left-module over <Lie algebra of dimension 8 over Rationals>>,  
<left-module over <Lie algebra of dimension
     8 over Rationals>> ]
gap> List( M, Dimension );
[ 8, 1 ]


I hope this answers your question.

Best wishes,

Willem de Graaf