[GAP Forum] A5 acting on 62 points

[Rudolf Zlabinger]

Dear Forums,

i dealt with group A5 and the icosahedron. I was eager to know, how to let act A5 on the 62 endpoints of the 31 axes of the geometric model of the icosahedron group. As it was to expensive to simply use IsomorphicSubgroups to Symmetric Group 62 I developed a way using the action homomorphisms on the 2, 3 and 5 cycles cosets, as outlined in the attachment.

I would like to know, whether there is a simpler way to do it, as I did, shown by the attachment containing a GAP session, only using permutation groups. If there is an error in my procedure, please give also feedback.

Best regards, Rudolf Zlabinger 
-------------- next part --------------
# The Icosahedron group naturally acts on 62 points as they are the 2 endpoints
# of the 31 axes the rotations are grouped around as cycles
# Here I try to get A5 work on the 62 endpoints of axes

# The basic idea is to represent the points by the cosets of the 2,3 and 5 cycles
# A5 is based on and let A5 act on them by the Action Homomorphisms

# The Images of the Action Homomorphisms of cycle 3 and 5 then are shifted by 30 and 50 to the right to
# get disjoint External Sets. The Action Homomorphisms of cycle 3 and 5 then are composed with the 
# Isomorphisms from the Action Images to the shifted groups.

# At the end the Images of the generators of A5 in all 3 resulting Homomorphisms are multiplicated for each A5 
# generator to get the generators of A5 acting on the 62 endpoints of the 31 axes.  



 
  a5:=AlternatingSubgroup(SymmetricGroup(5));;
  gena5:=GeneratorsOfGroup(a5);
  gens:=List([2,3,5],x->First(AsList(a5),y->Order(y)=x)); # look for 2,3 and 5 cycles
  cgroups:=List(gens,x->Group(x));                        # calculate the cyclic groups based on the cycles  
  
  cosets:=List(cgroups,x->RightCosets(a5,x));;                   # calculate cosets
  ahoms:=List(cosets,x->ActionHomomorphism(a5,x,OnRight));;      # calculate the Action Homomorphisms based on the latter
  images:=List(ahoms,Image);;                                    # calculate their Images  

# List(images,StructureDescription);
#[ "A5", "A5", "A5" ]
# List(images,NrMovedPoints);
#[ 30, 20, 12 ]
# List(images,x->Length(GeneratorsOfGroup(x)));
#[ 3, 3, 3 ]

  trans:=[                                         # transpositions
  (),                                              # to shift the 2 cycle Image by 0
  
  ( 1,31)( 2,32)( 3,33)( 4,34)( 5,35)              # to shift the 3 cycle Image by 30
  ( 6,36)( 7,37)( 8,38)( 9,39)(10,40)
  (11,41)(12,42)(13,43)(14,44)(15,45)
  (16,46)(17,47)(18,48)(19,49)(20,50),

  ( 1,51)( 2,52)( 3,53)( 4,54)( 5,55)( 6,56)       # and to shift the 5 cycle Image by 50
  ( 7,57)( 8,58)( 9,59)(10,60)(11,61)(12,62)

  ];

  shifted_images:=List([1..3],x-> images[x]^trans[x]); # calculate shifted images
  
  # calculate the Isomorphisms between the Images and the shifted Images 
  isomorphisms:=List([1..3],x->IsomorphismGroups(images[x],shifted_images[x]));
 
  # calculate the composed Homomorphisms between A5 and the shifted Images
  comps:=List([1..3],x-> ahoms[x]*isomorphisms[x]);

  # calculate the image generators for cycle 2 composed homomorphism
#  c2gens:=List(gena5,x->Image(comps[1],x));

  # calculate the image generators for cycle 3 composed homomorphism
#  c3gens:=List(gena5,x->Image(comps[2],x));

  # calculate the image generators for cycle 5 composed homomorphism
#  c5gens:=List(gena5,x->Image(comps[3],x));

  # collect the generator sets above for list processing
#  gensets:=[c2gens,c3gens,c5gens];

  # ore more simple
  gensets:=List(comps,x-> List(gena5,y->Image(x,y)));  

  # calculate the generators of the resulting A5 acting on 62 points
  # the generators can be assembled by permutation multiplication
  # as the components are disjoint; The number of generators in each set is 3

  generators:=List([1..3],x-> gensets[1][x]*gensets[2][x]*gensets[3][x]);

  # The resulting A5 acting on the 62 endpoints of the 31 axes is finally..
  a5_62:=Group(generators);