[GAP Forum] Conjugacy Class

[Derek Holt]

Dear GAP Forum, Alireza,

Here are a couple of GAP functions to construct SL(d,q):2 and PSL(d,q):2,
where the :2 is the graph (duality) automorphism. SL(d,q):2 is constructed
as a subgroup of GL(2d,q) geenrated by elements (in block form):

[  g   0    ]    and  [ 0 I ]
[  0   g^-T ]         [ I 0 ]

for g in SL(d,q).

Derek Holt.


SL2 := function(d,q)
  sl := SL(d,q);
  gsl := GeneratorsOfGroup(sl);
  gens := [];
  for g in gsl do
    Add( gens,
   MatrixByBlockMatrix(BlockMatrix([[1,1,g],[2,2,TransposedMat(g^-1)]],2,2)));
  od;
  i := IdentityMat(d,GF(q));
  Add( gens,
      MatrixByBlockMatrix(BlockMatrix([[1,2,i],[2,1,i]],2,2)) );
  return Subgroup( GL(2*d,q), gens );
end;

PSL2 := function(d,q)
   sl2 := SL2(d,q);
   v := Concatenation([1], 0*[1..2*d-1]) * Z(q)^0;
   return Action(sl2, Orbit(sl2,v,OnLines), OnLines);
end;

gap> c := ConjugacyClasses( PSL2(5,5) );;
gap> Length(c);
465


The conjugacy class computation took a couple of hours.



On Wed, Jul 26, 2006 at 01:39:12PM +0330, arashrafi wrote:
> Dear Pubbers,
> 
> Thank you very much from Sven Reichard, Leonard and  Scott Murray for 
> responding to my last message. The reality is this fact that I need the 
> conjecacy classes of the group PSL(5,5):2, but I know GAP library does 
> not have this group. Is there any possibility for including such 
> information on GAP?
> 
> All the best, Alireza
> -----------------------------------
> Ali Reza Ashrafi,
> Professor of Mathematics
> Department of Mathematics,
> Faculty of Science,
> University of Kashan,
> Kashan,Iran.
> 
> Tel: +98 361 5552935
> Fax: +98 361 5552930
> Mob: +98 912 5148260
> 
> E-mail: ashrafi at kashanu.ac.ir 
>         arashrafi at kashanu.ac.ir
>         ashrafi996 at yahoo.com
> -----------------------------------
> 
> _______________________________________________
> Forum mailing list
> Forum at mail.gap-system.org
> http://mail.gap-system.org/mailman/listinfo/forum