[GAP Forum] Ikosahedron exercises

[Rudolf Zlabinger]

Dear Gap Froum,

as i made my exercises on icosahedron, I will publish the results in case,
that you want to make use of them. As I can not fully guarant for
correctnes, please feel free, to send comments, especially in the case,
there is an error, syntactically, or in the content itself.

My first question was, to produce a list of groups isomorphic to a5
containing a specific permutation, acting on 12 points.
The second question was, to produce groups handling a specific distribution
of numbers 1..12 to the vertices of an icosahedron, I will name it labelling
set.
The third question was, how many labelling sets a specific group can handle,
with other words how to describe a set of labelling sets by selecting a
specific group.

0. Preparation: Find a group containing the specific permutation, both
acting on 12 points.

      ikosaeder_5:=AlternatingSubgroup(SymmetricGroup(5));

     s12:=SymmetricGroup(12);

     normact:=(2,3,4,5,6)(7,8,9,10,11);;
     # the desired rotation, e.g. the specific permutation

     ccnormact:=ConjugacyClass(s12,normact);
     # the conjugacyclass containing the rotation

     isos12:=IsomorphicSubgroups(s12,ikosaeder_5);
     # to mirror ikosaeder_5 to permgroups acting on 12 points

     iisos12:=List(isos12,c->Image(c));
     # to get groups

     selected_group:=First(iisos12,c->(NrMovedPoints(c)=12));
     # First group with desired Nr of moved points = 12

     enumgroup:=Enumerator(selected_group);
     # to prepare for efficiency

     intersect:=Intersection(enumgroup,ccnormact);
     # to get intersect of group to conjugacy class containing the desired
rotation

     grpact:=First(intersect,c->(Order(c)=5));
     # one permutation of the intersect of the selected group with order 5

     repop:=RepresentativeAction(s12,grpact,normact);
     # to get the desired conjugator

     cgroup:=selected_group^repop;
     # to get the desired conjugated group

     normact in cgroup;
     true      # the desired rotation is finally in the resulting group



1. Produce a list of groups isomorphic to A5 containing a specific
permutation, acting on 12 points. (Yet unsolved by me: is that list
complete? Are there more groups containing the specific permutation?)

The request is to select the permutations out of S12, that leave a group
generated by the specific permutation fixed, beeing the normalizer of that
generated group.

gap> normgrp:=Group([normact]);;
 # the group generated by the specific permutation

gap> normalizer:=Normalizer(s12,normgrp);
# the normalizer group leaving the above group fixed
Group([ (2,3,4,5,6)(7,8,9,10,11), (7,8,9,10,11), (1,12)(7,8,9,10,11),
  (3,6)(4,5)(7,11)(8,10), (3,5,6,4)(7,10,9,11), (2,7,6,8,5,9,4,10,3,11) ])
gap> Size(normalizer);
400

gap> orbcgroup:=Orbit(normalizer,cgroup);
# some (or all?) groups containing this specific permutation generated by
one group containing it
[ Group([ (1,2,3)(4,6,5)(7,8,12)(9,11,10), (1,2)(3,6)(7,12)(8,11) ]),
  Group([ (1,2,3)(4,6,5)(7,11,10)(8,9,12), (1,2)(3,6)(7,9)(8,12) ]),
  Group([ (1,2,3)(4,6,5)(7,11,8)(9,10,12), (1,2)(3,6)(8,10)(9,12) ]),
  Group([ (1,2,3)(4,6,5)(7,9,8)(10,11,12), (1,2)(3,6)(9,11)(10,12) ]),
  Group([ (1,2,3)(4,6,5)(7,12,11)(8,10,9), (1,2)(3,6)(7,10)(11,12) ]),
  Group([ (1,7,8)(2,3,12)(4,6,5)(9,11,10), (1,7)(2,12)(3,6)(8,11) ]),
  Group([ (1,8,9)(2,3,12)(4,6,5)(7,11,10), (1,8)(2,12)(3,6)(7,9) ]),
  Group([ (1,9,10)(2,3,12)(4,6,5)(7,11,8), (1,9)(2,12)(3,6)(8,10) ]),
  Group([ (1,10,11)(2,3,12)(4,6,5)(7,9,8), (1,10)(2,12)(3,6)(9,11) ]),
  Group([ (1,11,7)(2,3,12)(4,6,5)(8,10,9), (1,11)(2,12)(3,6)(7,10) ]) ]

gap> Length(orbcgroup);
10
gap> List(orbcgroup,c->(normact in c));
[ true, true, true, true, true, true, true, true, true, true ]


2. Produce a group handling a specific distribution of numbers 1..12 to the
vertices of an icosahedron

Having a blueprint in mind of icosahedron, there is a top vertex, two
pentagons one on top of another, the second pentagon rotated by 36 degrees
clockwise against the first one, and a bottom vertex.

As we label the top vertex by 1, the two pentagons by 2,3,4,5,6 and
7,8,9,10,11 clockwise looking in bottom direction respectively and the
bottom vertex by 12, we have following picture:

The respective opposite vertices are: (1,12), (2,9), (3,10), (4,11), (5,7),
(6,8).

The edges are:

(1,2),(1,3),(1,4),(1,5),(1,6),
from the top vertex to first pentagon
(12,7),(12,8)(12,9)(12,10)(12,11)
from the bottom vertex to second pentagon
(2,3)(3,4)(4,5)(5,6)(6,2)
the top pentagon
(7,8)(8,9)(9,10)(10,11)(11,7)
the bottom pentagon
(2,11)(2,7)(3,7)(3,8)(4,8)(4,9)(5,9)(5,10)(6,10)(6,11)
between the pentagons

This blueprint is induced from outside the formalism, and is to be
considered as starting point only, the rest ist handled by group theory.

The next step is to find a permutation of order 3 and of order 5 leaving
this blueprint fixed and thus generating A5:
(I developed a Excel Map containing this blueprint as an andjacent matrix
fixed by 2,3,5 cycle permutation matrices)

(2,3,4,5,6)(7,8,9,10,11)                 is the 5 cycle
(1,2,3)(7,4,6)(12,9,10)(5,11,8)      is the 3 cycle (is somewhat hard to
construct that in mind only)

gap> normact_5:=(2,3,4,5,6)(7,8,9,10,11);
(2,3,4,5,6)(7,8,9,10,11)

gap> normact_3:=(1,2,3)(7,4,6)(12,9,10)(5,11,8);
(1,2,3)(4,6,7)(5,11,8)(9,10,12)

gap> group10:=Group(normact_5,normact_3);
Group([ (2,3,4,5,6)(7,8,9,10,11), (1,2,3)(4,6,7)(5,11,8)(9,10,12) ])

gap> StructureDescription(group10);
"A5

3. How many labelling sets a specific group can handle, with other words how
to describe a set of labelling sets by selecting a specific group.

gap> nrmoved:=List(iisos12,c->NrMovedPoints(c));
# These are the number of moved points for each conjugacy class
# by a representative group of the isomorphic subgroups from A5 to S12

[ 5, 6, 10, 10, 11, 12, 12 ]

gap> sizenorm:=List(iisos12,c->Size(Normalizer(s12,c)));
# The normalizer tells us by size how many labelling sets leave
# each group by conjugacy class fixed.
# The sets of labellings sets forms S12

[ 604800, 86400, 480, 240, 120, 240, 240 ]

So the normalizer sizes tells us, how many labelling sets a group of a
conjugacy class can handle, and thus describe the labelling sets to some
degree inside the formalism. That is, for example, for the conjugacy classes
moving 12 points, a group can handle 240 different distinct labelling sets,
a group moving 11 points only 120. It woud be an extra task to enumerate,
what labelling sets these are on the blueprint.

The advantage of this construction is, that you can directly transfer the
(rotation) permutations to a solid model of icosahedron.

Best regards, Rudolf Zlabinger