[GAP Forum] Subgroup of PcGroup

[gapforum at mowsey.org]

It can be frustrating working with finite solvable groups
given by presentations in GAP. Most of the algorithms are
only available when the presenation is a pc-presentation in
which each element has prime relative order (this is called a
*refined* pc-presentation).

Here is a refined presentation for your group. Notice all
that was required was a generator to act as a place holder
for b^2. However, one must also calculate its action on the
other generators.

F:=FreeGroup( "b", "b2", "u", "v", "z");;
AssignGeneratorVariables(F);;
relators:=[b^2/b2, b2^2, u^3, v^3, z^3, u^b*v, v^b/u,
    u^b2*u, v^b2*v, Comm(b2,z),
    Comm(u,v), Comm(u,z), Comm(v,z), Comm(b,z)];;
G:=F/relators;;
OG:=Order(G);
Gpoly:=PcGroupFpGroup(G);;
AssignGeneratorVariables(Gpoly);;
Hpoly:=Subgroup(Gpoly,[u,v*z]);;
OH:=Order(Hpoly);

GAP also provides the function IsomorphismRefinedPcGroup
which takes a PcGroup and returns an isomorphism to a refined
PcGroup. You then use the isomorphism to transfer all of your
questions to the refined group. Here is your previous example
slightly modified:

F:=FreeGroup( "b", "u", "v", "z");;
AssignGeneratorVariables(F);;
relators:=[b^4, u^3, v^3, z^3, u^b*v, v^b/u,
    Comm(u,v), Comm(u,z), Comm(v,z), Comm(b,z)];;
G:=F/relators;;
OG:=Order(G);
Gpoly:=PcGroupFpGroup(G);;
AssignGeneratorVariables(Gpoly);;
Hpoly:=Subgroup(Gpoly,[u,v*z]);;
f:=IsomorphismRefinedPcGroup(Gpoly);
Href:=Image(f,Hpoly);
OH:=Order(Href);

p.s. The warning Stephen Kohl mentioned will be in the next
release of GAP, but was not in the 4.4.4 release.