Dear Royce Peng,

You asked:

I'm having trouble creating semidirect products; I am trying to create all
semidirect products of a group of order 8 with a group of order 6. The
example in the manual invokes functions like InverseGeneralMapping and
IsomorphismPCGroup, but I don't understand their purpose.

For creating a semidirect product one needs groups G,H and a homomorphism
from G into the automorphism group of H. The functions
`InverseGeneralMapping' and `IsomorphismPCGroup' in the manual example
are used for creating this homomorphism. It is not necessary to use them.
The following example creates the semidirect product of S_3 with S_4,
where S_3 acts on S_4 by conjugation.

# First we create the groups.
gap> G:= SymmetricGroup( 3 );
Sym( [ 1 .. 3 ] )
gap> H:= SymmetricGroup( 4 );
Sym( [ 1 .. 4 ] )
gap> eG:= Elements( G );;
gap> AH:= AutomorphismGroup( H );
<group with 2 generators>

# The we create the homomorphism by mapping each element `g' of `G'
# onto the autmorphism `h -> h^g' of `H'.
gap> imgs:= List( eG, g -> ConjugatorAutomorphism( H, g ) );
[ ^(), ^(2,3), ^(1,2), ^(1,2,3), ^(1,3,2), ^(1,3) ]
gap> hom:= GroupHomomorphismByImages( G, AH, eG, imgs );          
[ (), (2,3), (1,2), (1,2,3), (1,3,2), (1,3) ] -> 
[ ConjugatorAutomorphism( SymmetricGroup( [ 1 .. 4 ] ), () ), 
  ConjugatorAutomorphism( SymmetricGroup( [ 1 .. 4 ] ), (2,3) ), 
  ConjugatorAutomorphism( SymmetricGroup( [ 1 .. 4 ] ), (1,2) ), 
  ConjugatorAutomorphism( SymmetricGroup( [ 1 .. 4 ] ), (1,2,3) ), 
  ConjugatorAutomorphism( SymmetricGroup( [ 1 .. 4 ] ), (1,3,2) ), 
  ConjugatorAutomorphism( SymmetricGroup( [ 1 .. 4 ] ), (1,3) ) ]

# Finally we create the semidirect product.
gap> P:= SemidirectProduct( G, hom, H );
<permutation group with 4 generators>

I hope this is of help. Sorry for answering so late.

Best wishes,

Willem de Graaf

School of Mathematical and Computational Sciences
University of St Andrews
North Haugh                     Tel:  +44 1334 463273
St Andrews                      Email: wdg@dcs.st-and.ac.uk
Fife      KY16 9SS             
Scotland