> GAP>LatticeSubgroups(G);
> <subgroup lattice of Sym( [ 1 .. 3 ] ), 4 classes, 6 subgroups>
>
> I don't understand how I can construct the full lattice when I know only
> the number of Conjugacy Classes and the number of Subgroups.
>
Hi Bjorn,

Once you computed the subgroup lattice, other commands help you to find
out more about it. An Example is "MaximalSubgroups". Let's see how this
works on your example:

gap> g:=SymmetricGroup(3);;  
gap> lat:=LatticeSubgroups(g);  
<subgroup lattice of Sym( [ 1 .. 3 ] ), 4 classes, 6 subgroups> 
gap> classes:=ConjugacyClassesSubgroups(lat);  
[ Group( () )^G, Group( [ (2,3) ] )^G, Group( [ (1,2,3) ] )^G,
  SymmetricGroup( [ 1 .. 3 ] )^G ] 
gap> lengths:=List(classes, Size);  
[1, 3, 1, 1 ] 

# Hence the lattice has 4 conjugacy classes, one of length 3 and 3 of
# length 1. These are three normal subgroups!
# Now we take representatives in the classes...

gap> repr:=List(classes, Representative);  
[ Group(()), Group([ (2,3) ]), Group([ (1,2,3) ]), Sym( [ 1 .. 3 ] ) ]
gap>   sizes:=List(repr, Size);
[ 1, 2, 3, 6 ]

# OK. Now we know the groups in our classes.

gap> maxsg:=MaximalSubgroupsLattice(lat);  
[ [ ], [ [ 1, 1 ] ], [ [ 1, 1 ] ],
  [ [ 3, 1 ], [ 2, 1 ], [ 2, 2 ], [ 2, 3 ] ] ]

# Here we see that the groups in the first class have no subgroups. Of
# course! The groups in that class are trivial.
# A representative of the second class contains a group of the first class
# as a maximal subgroup. The same is true for a representative of the
# third class. A representative of the fourth class (i.e. the group Sym(3)
# itself) contains the group of the third class and all three groups of
# the second class as maximal subgroups.

With this information you can make a picture of the subgroup lattice of
Sym(3). More commands like this are available in GAP: just check the
manual. As an exercise, you should try the command
"MinimalSupergroupsLattice".

I have some experience with subgroup lattices in GAP. If you need more
information, I'll be happy to help you. Some years ago, I wrote a program
which generates a LaTeX file with the subgroup lattice of a given group
in the form of a table. This enables you to work in the subgroup lattice
if needed. If you really want a picture, you should take a
look at xgap but beware that subgroup lattices rapidly become very
complicated and difficult to draw.

Best regards,

Philippe Cara

Miles-Receive-Header: reply