Goto Chapter: Top 1 2 3 4 5 6 7 8 9 Ind
 [Top of Book]  [Contents]   [Previous Chapter]   [Next Chapter] 

5 Affine toric varieties
 5.1 Affine toric varieties: Examples
 5.2 The GAP category
 5.3 Attributes
 5.4 Methods
 5.5 Constructors

5 Affine toric varieties

5.1 Affine toric varieties: Examples

5.1-1 Affine space
gap> F := Fan( [[1,0,0],[0,1,0],[0,0,1]], [[1,2,3]] );
<A fan in |R^3>
gap> C3 := ToricVariety( F );
<A toric variety of dimension 3>
gap> IsAffine( C3 );
true
gap> Dimension( C3 );
3

More conveniently, we can build affine toric varieties from a cone:

gap> IsAffine( ProjectiveSpace( 1 ) );
false
gap> C:=Cone( [[1,0,0],[0,1,0],[0,0,1]] );
<A cone in |R^3>
gap> C3:=ToricVariety(C);
<An affine normal toric variety of dimension 3>
gap> Dimension(C3);
3
gap> IsSimplicial( C3 );
true
gap> IsOrbifold(C3);
true
gap> IsSmooth(C3);
true
gap> IsProjective( C3 );
false
gap> DimensionOfTorusfactor( C3 );
0
gap> CoordinateRingOfTorus(C3,"x");
Q[x1,x1_,x2,x2_,x3,x3_]/( x1*x1_-1, x2*x2_-1, x3*x3_-1 )
gap> CoordinateRing(C3,"x");
Q[x_1,x_2,x_3]
gap> ListOfVariablesOfCoordinateRing( C3 );
[ "x_1", "x_2", "x_3" ]
gap> MorphismFromCoordinateRingToCoordinateRingOfTorus( C3 );
<A monomorphism of rings>
gap> C3;
<An affine normal smooth toric variety of dimension 3>
gap> StructureDescription( C3 );
"|A^3"
gap> ConeOfVariety( C3 );
<A smooth pointed simplicial cone in |R^3 with 3 ray generators>
gap> Cone( C3 );
<A smooth pointed simplicial cone in |R^3 with 3 ray generators>
gap> IrrelevantIdeal( C3 );
<A graded principal torsion-free (left) ideal given by a cyclic generator>
gap> CartierTorusInvariantDivisorGroup( C3 );
<A free left submodule given by 3 generators>
gap> v:=Cone( [[1,0,0],[0,1,0]] );
<A cone in |R^3>
gap> v:=ToricVariety(v);
<An affine normal toric variety of dimension 3>
gap> DimensionOfTorusfactor( v );
1
gap> CartierTorusInvariantDivisorGroup( v );
<A free left submodule given by 3 generators>
gap> ConeOfVariety( v );
<A pointed cone in |R^3 of dimension 2 with 2 ray generators>
gap> Cone( v );
<A pointed cone in |R^3 of dimension 2 with 2 ray generators>
gap> v2:=Cone( [[1,1],[-1,1]] );
<A cone in |R^2>
gap> v2:=ToricVariety(v2);
<An affine normal toric variety of dimension 2>
gap> IsSmooth( v2 );
false
gap> Display( v2 );
An affine normal non smooth toric variety of dimension 2.
gap> ConeOfVariety( v * v2 );
<A pointed cone in |R^5>

5.2 The GAP category

5.2-1 IsAffineToricVariety
‣ IsAffineToricVariety( M )( filter )

Returns: true or false

The GAP category of an affine toric variety. All affine toric varieties are toric varieties, so everything applicable to toric varieties is applicable to affine toric varieties.

5.3 Attributes

5.3-1 CoordinateRing
‣ CoordinateRing( vari )( attribute )

Returns: a ring

Returns the coordinate ring of the affine toric variety vari.

5.3-2 ListOfVariablesOfCoordinateRing
‣ ListOfVariablesOfCoordinateRing( vari )( attribute )

Returns: a list

Returns a list containing the variables of the CoordinateRing of the variety vari.

5.3-3 MorphismFromCoordinateRingToCoordinateRingOfTorus
‣ MorphismFromCoordinateRingToCoordinateRingOfTorus( vari )( attribute )

Returns: a morphism

Returns the morphism between the coordinate ring of the variety vari and the coordinate ring of its torus. This defines the embedding of the torus in the variety.

5.3-4 ConeOfVariety
‣ ConeOfVariety( vari )( attribute )

Returns: a cone

Returns the cone of the affine toric variety vari.

5.4 Methods

5.4-1 CoordinateRing
‣ CoordinateRing( vari, indet )( operation )

Returns: a ring

Computes the coordinate ring of the affine toric variety vari with indeterminates indet.

5.4-2 Cone
‣ Cone( vari )( operation )

Returns: a cone

Returns the cone of the variety vari. Another name for ConeOfVariety for compatibility and shortness.

5.5 Constructors

The constructors are the same as for toric varieties. Calling them with a cone will result in an affine variety.

 [Top of Book]  [Contents]   [Previous Chapter]   [Next Chapter] 
Goto Chapter: Top 1 2 3 4 5 6 7 8 9 Ind

generated by GAPDoc2HTML