> < ^ Date: Wed, 18 Sep 2002 10:07:38 -0600 (MDT)
> < ^ From: Alexander Hulpke <hulpke@math.colostate.edu >
< ^ Subject: Re: Projection onto direct product components of a wreath product

Dear Gap-Forum,

Avital Oliver wrote:

If I construct a wreath product using WreathProduct(G, P), when P is a
permutation group of degree k, how can I get a projection onto the k copies
of G in the direct product base of the wreath product? The documentation
makes it seem as if it is only possible to get the projection onto P. Is
this true?

The projections on the components are defined only on a subgroup of the
wreath product, and therefore not provided by GAP.

To get these, you have two possibilities, both requiring to get this
subgroup first:

Option a) constructs the projections from the embeddings in the base group:

gap> a5:=AlternatingGroup(5);  
Alt( [ 1 .. 5 ] )
gap> s3:=SymmetricGroup(3);
Sym( [ 1 .. 3 ] )
gap> w:=WreathProduct(a5,s3);
<permutation group of size 1296000 with 8 generators>
gap> b:=Kernel(Projection(w));
Group([ (1,2,3,4,5), (3,4,5), (6,7,8,9,10), (8,9,10), (11,12,13,14,15), 
  (13,14,15) ])
gap> Size(b);
216000
gap> agens:=GeneratorsOfGroup(a5);
[ (1,2,3,4,5), (3,4,5) ]
gap> egens:=List([1..3],i->List(agens,j->Image(Embedding(w,i),j)));
[ [ (1,2,3,4,5), (3,4,5) ], [ (6,7,8,9,10), (8,9,10) ], 
  [ (11,12,13,14,15), (13,14,15) ] ]
# for example projection on 2nd component, Replace 2 by component number
gap> proj2:=GroupHomomorphismByImages(b,a5,Concatenation(egens),
> Concatenation(List([1..(2-1)*Length(agens)],i->One(a5)),
> agens,  
> List([1..(3-2)*Length(agens)],i->One(a5))));

Option b) (works only for permutation groups) uses the fact that the base
group is as a permutation group the same as a direct power:

gap> b:=DirectProduct(a5,a5,a5);
Group([ (1,2,3,4,5), (3,4,5), (6,7,8,9,10), (8,9,10), (11,12,13,14,15), 
  (13,14,15) ])
gap> Projection(b,2);
2nd projection of Group([ (1,2,3,4,5), (3,4,5), (6,7,8,9,10), (8,9,10), 
  (11,12,13,14,15), (13,14,15) ])

I hope this helps,

Alexander Hulpke

-- Colorado State University, Department of Mathematics,
Weber Building, Fort Collins, CO 80523, USA
email: hulpke@math.colostate.edu, Phone: ++1-970-4914288
http://www.math.colostate.edu/~hulpke


> < [top]